DEFINT A-Z
DECLARE SUB Square (n, c)
DECLARE SUB Inc (nn)
DIM q(9)
COLOR , 1: CLS
RANDOMIZE TIMER
FOR i = 1 TO 9
    q(i) = INT(RND * 5)
IF q(i) < 3 THEN q(i) = 0 ELSE q(i) = 1
    Square i, q(i)
NEXT
DO
   DO
DO: a$ = INKEY$: LOOP UNTIL LEN(a$)
      a = VAL(a$)
      IF a$ = CHR$(27) THEN END
      IF q(a) = 0 THEN SOUND 300, .3
   LOOP UNTIL q(a) = 1: Inc q(a)
   SELECT CASE a
CASE 1: Inc q(2): Inc q(4): Inc q(5)
CASE 2: Inc q(1): Inc q(3)
CASE 3: Inc q(2): Inc q(5): Inc q(6)
CASE 4: Inc q(1): Inc q(7)
CASE 5: Inc q(2): Inc q(4): Inc q(6): Inc q(8)
CASE 6: Inc q(3): Inc q(9)
CASE 7: Inc q(4): Inc q(5): Inc q(8)
CASE 8: Inc q(7): Inc q(9)
CASE 9: Inc q(5): Inc q(6): Inc q(8)
   END SELECT
   FOR i = 1 TO 9
       IF q(i) = 2 THEN q(i) = 0
       Square i, q(i)
   NEXT
   e = 0
   FOR i = 1 TO 9
       IF q(i) = 1 THEN Inc e
   NEXT
LOOP UNTIL e = 0 OR (e = 8 AND q(5) = 0)
LOCATE 22, 35: COLOR , 1
IF e = 0 THEN PRINT "Leider verloren" ELSE PRINT "   Geschafft!"

SUB Inc (nn)
nn = nn + 1
END SUB

SUB Square (n, c)
s$ = SPACE$(10)
    COLOR , c + 3
    SELECT CASE n
           CASE 1, 2, 3: y = 1
           CASE 4, 5, 6: y = 7
           CASE 7, 8, 9: y = 13
    END SELECT
    SELECT CASE n
           CASE 3, 6, 9: x = 25
           CASE 2, 5, 8: x = 13
           CASE 1, 4, 7: x = 1
    END SELECT
    FOR e = 1 TO 5
        LOCATE y + e + 2, x + 24
        PRINT s$
    NEXT
    LOCATE y + 2 + 3, x + 4 + 24
    COLOR 15, c + 3: PRINT n
END SUB