'Sounds like you need much more accuracy than this.
#COMPILE EXE
#DIM ALL
DECLARE FUNCTION PlaySound LIB "WINMM.DLL" ALIAS "PlaySoundA" (lpszName AS ASCIIZ, BYVAL hModule AS DWORD, BYVAL dwFlags AS DWORD) AS LONG
DECLARE SUB Play(filenam AS STRING)
%HWND_BROADCAST = &HFFFFFFFF???
%WM_WININICHANGE     = &H1A
%WM_SETTINGCHANGE    = %WM_WININICHANGE
TYPE SYSTEMTIME
  wYear AS WORD
  wMonth AS WORD
  wDayOfWeek AS WORD
  wDay AS WORD
  wHour AS WORD
  wMinute AS WORD
  wSecond AS WORD
  wMilliseconds AS WORD
END TYPE
DECLARE FUNCTION SetSystemTime LIB "KERNEL32.DLL" ALIAS "SetSystemTime" (lpSystemTime AS SYSTEMTIME) AS LONG
DECLARE FUNCTION SendMessage LIB "USER32.DLL" ALIAS "SendMessageA" (BYVAL hWnd AS DWORD, BYVAL dwMsg AS DWORD, BYVAL wParam AS DWORD, BYVAL lParam AS LONG) AS LONG
$site="time-a.timefreq.bldrdoc.gov"

FUNCTION PBMAIN AS LONG
   CALL TimeServ
END FUNCTION
FUNCTION TimeServ AS LONG
    LOCAL OpenAttempts AS LONG
    LOCAL ff AS LONG, buffer1$,buffer2$, s$,result&
    DO
      IF OpenAttempts THEN BEEP  'wasn't successful first time
      INCR OpenAttempts
      FF& = FREEFILE
      TCP OPEN PORT 13 AT $site AS ff TIMEOUT 4000
    LOOP UNTIL ERR = 0 OR OpenAttempts >5  'until success or too many
    IF ERR OR OpenAttempts >5 THEN
        BEEP
        MSGBOX "Unable to open " & $site & " on port 13"
        EXIT FUNCTION
    END IF
    TCP LINE INPUT #FF&, Buffer1$
    TCP LINE INPUT #FF&, Buffer2$
    TCP CLOSE #FF&
    DIM v AS SYSTEMTIME
    S$ = PARSE$(Buffer2$, " ", 2)
    v.wYear = VAL(PARSE$(S$, "-", 1)) + 2000
    v.wMonth = VAL(PARSE$(S$, "-", 2))
    v.wDay = VAL(PARSE$(S$, "-", 3))
    S$ = PARSE$(Buffer2$, " ", 3)
    v.wHour = VAL(PARSE$(S$, ":", 1))
    v.wMinute = VAL(PARSE$(S$, ":", 2))
    v.wSecond = VAL(PARSE$(S$, ":", 3))
    SetSystemTime v
    SendMessage %HWND_BROADCAST, %WM_SETTINGCHANGE, 0&, 0&
    CALL Play ("\windows\media\tada.wav")
END FUNCTION

SUB Play (filenam AS STRING)
  %NULL = 0
  %SND_SYNC = &H0 ' play synchronously (default)
  LOCAL x AS LONG, y AS LONG
  LOCAL zWav AS ASCIIZ * 256
  zWav = filenam
  CALL PlaySound(zWav, %NULL ,%SND_SYNC) 'use sync so sound file completes
END SUB

'time-a.nist.gov 129.6.15.28 NIST, Gaithersburg, Maryland
'time-b.nist.gov 129.6.15.29 NIST, Gaithersburg, Maryland
'time-a.timefreq.bldrdoc.gov 132.163.4.101 NIST, Boulder, Colorado
'time-b.timefreq.bldrdoc.gov 132.163.4.102 NIST, Boulder, Colorado
'time-c.timefreq.bldrdoc.gov 132.163.4.103 NIST, Boulder, Colorado
'utcnist.colorado.edu 128.138.140.44 University of Colorado, Boulder
'time.nist.gov 192.43.244.18 NCAR, Boulder, Colorado
'time-nw.nist.gov 131.107.1.10 Microsoft, Redmond, Washington
'nist1.datum.com 66.243.43.21 Datum, San Jose, California
'nist1-dc.glassey.com 216.200.93.8 Abovenet, Virginia
'nist1-ny.glassey.com 208.184.49.9 Abovenet, New York City
'nist1-sj.glassey.com 207.126.98.204 Abovenet, San Jose, California
'nist1.aol-ca.truetime.com 207.200.81.113 TrueTime, AOL facility, Sunnyvale, California
'nist1.aol-va.truetime.com 205.188.185.33 TrueTime, AOL facility, Virginia